DJSON-46 Add :extra-data-fn to read - if provided and a json value has been read, the strema will be checked for remaining unread data and the function called if found

Signed-off-by: Alex Miller <alex.miller@cognitect.com>

Author: puredanger

src/main/clojure/clojure/data/json.clj

@@ -363,6 +363,34 @@
           (throw (Exception.
                   (str "JSON error (unexpected character): " (char c))))))))
 
+(defn- -read1
+  [^PushbackReader stream eof-error? eof-value options]
+  (let [val (-read stream eof-error? eof-value options)]
+    (if-let [extra-data-fn (:extra-data-fn options)]
+      (if (or eof-error? (not (identical? eof-value val)))
+        (let [c (.read stream)]
+          (if (neg? c)
+            val
+            (do
+              (.unread stream c)
+              (extra-data-fn val stream))))
+        val)
+      val)))
+
+(defn on-extra-throw
+  "Pass as :extra-data-fn to `read` or `read-str` to throw if data is found
+  after the first object."
+  [val rdr]
+  (throw (ex-info "Found extra data after json object" {:val val})))
+
+(defn on-extra-throw-remaining
+  "Pass as :extra-data-fn to `read` or `read-str` to throw if data is found
+  after the first object and return the remaining data in ex-data :remaining."
+  [val ^java.io.PushbackReader rdr]
+  (let [remaining (slurp rdr)]
+    (throw (ex-info (str "Found extra data after json object: " remaining)
+             {:val val, :remaining remaining}))))
+
 (def default-read-options {:bigdec false
                            :key-fn nil
                            :value-fn nil})
@@ -404,7 +432,14 @@
         in the output. If value-fn returns itself, the property will
         be omitted from the output. The default value-fn returns the
         value unchanged. This option does not apply to non-map
-        collections."
+        collections.
+
+     :extra-data-fn function
+
+       If :extra-data-fn is not nil, then the reader will be checked
+       for extra data after the read. If found, the extra-data-fn will
+       be invoked with the read value and the reader. The result of
+       the extra-data-fn will be returned."
   [reader & {:as options}]
   (let [{:keys [eof-error? eof-value]
          :or {eof-error? true}} options
@@ -413,7 +448,7 @@
               (PushbackReader. reader 64))]
     (->> options
          (merge default-read-options)
-         (-read pbr eof-error? eof-value))))
+         (-read1 pbr eof-error? eof-value))))
 
 (defn read-str
   "Reads one JSON value from input String. Options are the same as for
@@ -423,7 +458,7 @@
          :or {eof-error? true}} options]
     (->> options
          (merge default-read-options)
-         (-read (PushbackReader. (StringReader. string) 64) eof-error? eof-value))))
+         (-read1 (PushbackReader. (StringReader. string) 64) eof-error? eof-value))))
 
 ;;; JSON WRITER
 

src/test/clojure/clojure/data/json_test.clj

@@ -35,6 +35,35 @@
   (is (= 123456789012345678901234567890N
          (json/read-str "123456789012345678901234567890"))))
 
+(deftest lenient-on-extra-data
+  (is (= [42] (json/read-str "[42],abc")))
+  (is (= [42] (json/read (java.io.StringReader. "[42],abc")))))
+
+(deftest strict-on-extra-data
+  ;; on-extra-throw
+  (is (thrown? clojure.lang.ExceptionInfo
+        (json/read-str "[42],abc" :extra-data-fn json/on-extra-throw)))
+  (is (thrown? clojure.lang.ExceptionInfo
+        (json/read (java.io.StringReader. "[42],abc") :extra-data-fn json/on-extra-throw)))
+
+  ;; on-extra-throw-remaining
+  (try
+    (json/read-str "[42],abc" :extra-data-fn json/on-extra-throw-remaining)
+    (is false "expected exception to be thrown")
+    (catch clojure.lang.ExceptionInfo e
+      (is (= ",abc" (:remaining (ex-data e))))))
+  (try
+    (json/read-str "[1], 1]" :extra-data-fn json/on-extra-throw-remaining)
+    (is false "expected exception to be thrown")
+    (catch clojure.lang.ExceptionInfo e
+      (is (= ", 1]" (:remaining (ex-data e))))))
+
+  ;; check that empty input behavior not modified when :extra-data-fn specified
+  (is (= :hi (json/read-str ""
+               :eof-error? false, :eof-value :hi, :extra-data-fn json/on-extra-throw)))
+  (is (= :hi (json/read (java.io.StringReader. "")
+               :eof-error? false, :eof-value :hi, :extra-data-fn json/on-extra-throw))))
+
 (deftest write-bigint
   (is (= "123456789012345678901234567890"
          (json/write-str 123456789012345678901234567890N))))