|
| 1 | +class_name HighlightsOverlay |
| 2 | +extends Control |
| 3 | + |
| 4 | + |
| 5 | +class AnimatedConnection extends Line2D: |
| 6 | + var connection : Dictionary |
| 7 | + |
| 8 | +@onready var graph : MMGraphEdit = owner |
| 9 | + |
| 10 | +var active_connections : Array[Dictionary] |
| 11 | +var is_updating_connections := false |
| 12 | + |
| 13 | +const LINE_MATERIAL := preload("res://material_maker/panels/graph_edit/animated_connection.tres") |
| 14 | + |
| 15 | +func _ready() -> void: |
| 16 | + graph.child_order_changed.connect(_move_above_connections.call_deferred) |
| 17 | + graph.get_node("_connection_layer").draw.connect(queue_redraw) |
| 18 | + graph.get_node("_connection_layer").child_order_changed.connect(update_connections) |
| 19 | + graph.connection_drag_started.connect(update_connections.bind(1).unbind(3)) |
| 20 | + graph.node_selected.connect(update_connections.unbind(1)) |
| 21 | + graph.node_deselected.connect(update_connections.unbind(1)) |
| 22 | + graph.gui_input.connect(_graph_gui_input) |
| 23 | + |
| 24 | +func _draw() -> void: |
| 25 | + if get_children().is_empty(): |
| 26 | + return |
| 27 | + |
| 28 | + for line : AnimatedConnection in get_children(): |
| 29 | + var conn : Dictionary = line.connection |
| 30 | + var positions := get_connection_positions(conn) |
| 31 | + if positions.is_empty(): |
| 32 | + continue |
| 33 | + |
| 34 | + line.visible = get_viewport_rect().intersects( |
| 35 | + Rect2(positions.from, positions.to - positions.from).abs()) |
| 36 | + |
| 37 | + line.points = graph._get_connection_line(positions.from, positions.to) |
| 38 | + line.width = graph.connection_lines_thickness |
| 39 | + |
| 40 | +func _move_above_connections() -> void: |
| 41 | + graph.move_child(self, graph.get_node("_connection_layer").get_index() + 1) |
| 42 | + |
| 43 | +func _graph_gui_input(e : InputEvent) -> void: |
| 44 | + if e is InputEventKey: |
| 45 | + update_connections(true) |
| 46 | + |
| 47 | +func update_connections(should_hide_when_updating : bool = false) -> void: |
| 48 | + if is_updating_connections: |
| 49 | + return |
| 50 | + is_updating_connections = true |
| 51 | + |
| 52 | + if should_hide_when_updating: |
| 53 | + hide() |
| 54 | + |
| 55 | + while Input.is_mouse_button_pressed(MOUSE_BUTTON_LEFT): |
| 56 | + await get_tree().process_frame |
| 57 | + |
| 58 | + active_connections.clear() |
| 59 | + for c in graph.get_connection_list(): |
| 60 | + if (graph.get_node(NodePath(c.from_node)).selected |
| 61 | + or graph.get_node(NodePath(c.to_node)).selected): |
| 62 | + active_connections.append(c) |
| 63 | + await get_tree().process_frame |
| 64 | + create_animated_connections() |
| 65 | + |
| 66 | + # Remove inactive/invalid animated conections |
| 67 | + if get_children().size(): |
| 68 | + for anim_line : AnimatedConnection in get_children(): |
| 69 | + if (anim_line.connection not in active_connections |
| 70 | + or get_connection_positions(anim_line.connection).is_empty()): |
| 71 | + remove_child(anim_line) |
| 72 | + anim_line.free() |
| 73 | + |
| 74 | + queue_redraw() |
| 75 | + is_updating_connections = false |
| 76 | + show.call_deferred() |
| 77 | + |
| 78 | +func create_animated_connections() -> void: |
| 79 | + if active_connections.size(): |
| 80 | + for active_connection in active_connections: |
| 81 | + var positions := get_connection_positions(active_connection) |
| 82 | + if positions.is_empty(): |
| 83 | + continue |
| 84 | + |
| 85 | + var has_existing_connection : bool = false |
| 86 | + for c in get_children(): |
| 87 | + if c.connection == active_connection: |
| 88 | + has_existing_connection = true |
| 89 | + break |
| 90 | + |
| 91 | + if not has_existing_connection: |
| 92 | + var ac := AnimatedConnection.new() |
| 93 | + ac.connection = active_connection |
| 94 | + ac.texture_mode = Line2D.LINE_TEXTURE_TILE |
| 95 | + ac.material = LINE_MATERIAL |
| 96 | + ac.points = graph._get_connection_line(positions.from, positions.to) |
| 97 | + ac.width = graph.connection_lines_thickness |
| 98 | + add_child(ac) |
| 99 | + |
| 100 | +func get_connection_positions(from_connection : Dictionary) -> Dictionary: |
| 101 | + var c := from_connection |
| 102 | + var positions : Dictionary |
| 103 | + if graph.has_node(NodePath(c.from_node)) and graph.has_node(NodePath(c.to_node)): |
| 104 | + var from_node : GraphNode = graph.get_node(NodePath(c.from_node)) |
| 105 | + var to_node : GraphNode = graph.get_node(NodePath(c.to_node)) |
| 106 | + if from_node and to_node: |
| 107 | + var from_pos := from_node.get_output_port_position(c.from_port) |
| 108 | + var to_pos := to_node.get_input_port_position(c.to_port) |
| 109 | + positions.from = from_pos * graph.zoom + from_node.position |
| 110 | + positions.to = to_pos * graph.zoom + to_node.position |
| 111 | + return positions |
0 commit comments