FZX-lib/CMakeLists.txt at main · FahdSeddik/FZX-lib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
cmake_minimum_required(VERSION 3.10)

# Read version
file(READ VERSION FZX_VERSION)
string(STRIP "${FZX_VERSION}" FZX_VERSION)

project(FZX
    VERSION ${FZX_VERSION}
    DESCRIPTION "Header-only C++ 3D physics engine library"
    LANGUAGES CXX
)

# Basic install dirs
include(GNUInstallDirs)

# Default build type
set(default_build_type "Release")
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  message(STATUS "Setting build type to '${default_build_type}' as none was specified.")
  set(CMAKE_BUILD_TYPE "${default_build_type}" CACHE STRING "Choose the type of build." FORCE)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
endif()

# Precision option
option(FZX_DOUBLE_PRECISION "Use double precision for physics calculations" OFF)

# Tests option
option(FZX_COMPILE_TESTS "Compile the FZX test suite" ON)

# Define the header-only interface library
add_library(fzx INTERFACE)
add_library(FZX::fzx ALIAS fzx)

target_include_directories(fzx INTERFACE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)

target_compile_features(fzx INTERFACE cxx_std_17)
target_compile_options(fzx INTERFACE $<$<CONFIG:Debug>:-g>)
target_compile_options(fzx INTERFACE $<$<CONFIG:Release>:-O3>)
set_target_properties(fzx PROPERTIES CXX_EXTENSIONS OFF)

# Precision defines
if(FZX_DOUBLE_PRECISION)
    target_compile_definitions(fzx INTERFACE FZX_DOUBLE_PRECISION)
    message(STATUS "FZX: using double precision")
else()
    target_compile_definitions(fzx INTERFACE FZX_SINGLE_PRECISION)
    message(STATUS "FZX: using single precision")
endif()

# Testing
if(FZX_COMPILE_TESTS)
    message(STATUS "Configuring FZX test suite")
    add_subdirectory(test)
endif()

# Installation
install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

# Export target for find_package
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/FZXConfigVersion.cmake"
    VERSION ${FZX_VERSION}
    COMPATIBILITY AnyNewerVersion
)

configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/FZXConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/FZXConfig.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/FZX
)

install(TARGETS fzx
    EXPORT fzx-targets
    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

install(EXPORT fzx-targets
    FILE FZXTargets.cmake
    NAMESPACE FZX::
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/FZX
)

install(FILES
    "${CMAKE_CURRENT_BINARY_DIR}/FZXConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/FZXConfigVersion.cmake"
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/FZX
)